>>>>> "DG" == Daniele Gratteri <daniele_gratteri@inwind.it> writes:
DG> I have checked it a lot of times and it seems to be OK. If i type
DG> PRINT A, the VIC 20 says 40960...
?40960AND255
?ILLEGAL QUANTITY ERROR
READY.
on both the C64 and the VIC-20. Looks like it can't handle numbers
over 32767. Here's a new version of the memory test program (lines
with a * have been added or modified)
10 input "test which block";b
20 s = b*8192 : t = s+8191 : e = 0 : o = 0
* 25 if s>= 32768 then s = s-32768 : t = s+8191 : o = 32768
30 print "testing databus"
* 40 for a = s to t : poke a+o, 85 : if peek(a+o) <> 85 then gosub 1000
* 50 poke a+o, 170 : if peek(a+o) <> 170 then gosub 1000
60 next : de = e
70 e=0 : print "testing high address bus"
* 80 for a = s to t : poke a+o, int(a/256) : next
* 90 for a = s to t : if peek(a+o) <> int(a/256) then gosub 1000
100 next : he = e
110 e=0 : print "testing low address bus"
* 120 for a = s to t : poke a+o, a and 255 : next
* 130 for a = s to t : if peek(a+o) <> (a and 255) then gosub 1000
140 next : print ^- also added parenthesis
150 print de;"errors found in databus test"
160 print he;"errors found in high address bus test"
170 print e;"errors found in low address bus test"
999 end
1000 e = e+1 : print "error at";a : return
--
___ . . . . . + . . o
_|___|_ + . + . + . . Per Olofsson, konstnär
o-o . . . o + MagerValp@cling.gu.se
- + + . http://www.cling.gu.se/~cl3polof/
Message was sent through the cbm-hackers mailing list
Archive generated by hypermail 2.1.1.